% Special version of Computer Modern for \TeX's extended ASCII character set

font_coding_scheme:="TeX extended ASCII";

mode_setup; font_setup;

input tsetsl;	% special symbols to be slanted
slant:=mono_charic#:=0;	% the remaining characters will not be slanted
currenttransform:=identity yscaled aspect_ratio scaled granularity;

input romanu;	% upper case (majuscules)
input romanl;	% lower case (minuscules)
input romand;	% numerals
input romanp;	% ampersand, question marks, currency sign
input punct;	% punctuation symbols common to roman and italic text
input tset;	% remaining special symbols of extended ASCII

font_xheight x_height#;
if monospace: font_normal_space 9u#; % no stretching or shrinking
 font_quad 18u#;
 font_extra_space 9u#;
else: font_normal_space 6u#+2letter_fit#;
 font_normal_stretch 3u#; font_normal_shrink 2u#;
 font_quad 18u#+4letter_fit#;
 font_extra_space 2u#;
 numeric k,kk,kkk; k=-.5u#; kk=-1.5u#; kkk=-2u#; % three degrees of kerning
 ligtable "k": "v": "a" kern -u#, "w": "a" kern k,
  "o" kern k, "e" kern k, "c" kern k;
 ligtable "P": "A" kern kk,
  "y": "a" kern k, "o" kern k, "e" kern k, "." kern kk, "," kern kk;
 ligtable "F": "V": "W": "A" kern kkk,
   "o" kern kk, "e" kern kk, "a" kern kk, "u" kern kk, "r" kern kk,
  "K": "X": "O" kern k, "C" kern k, "G" kern k, "Q" kern k;
 ligtable "T": "y" kern if serifs: k else: kk fi,
  "Y": "u" kern kk, "r" kern kk,
   "o" kern kk, "e" kern kk, "a" kern kk, "A" kern kk;
 ligtable "O": "D": "A" kern k, "W" kern k, "Y" kern k, "V" kern k, "X" kern k;
 if serifs: ligtable "h": "m": "n":
   "t" kern k, "u" kern k, "b" kern k, "y" kern k, "w" kern k, "v" kern k;
  ligtable "c": "h" kern k, "k" kern k; fi
 ligtable "o": "b": "p": "e" kern -k, "o" kern -k, "c" kern -k,
   "d" kern -k, "q" kern -k, "x" kern k,
  "a": "v" kern k,
  "t": "y" kern k,
  "u": "w" kern k;
 ligtable "A": if serifs: "R": fi "t" kern k,
  "L": "T" kern kk, "O" kern k, "U" kern k, "C" kern k,
   "W" kern kkk, "Y" kern kk, "G" kern k, "V" kern kkk, "Q" kern k;
 ligtable "g": "j" kern k; % logjam
 ligtable "I": "I" kern -k; % Richard III
fi;
if known Xerox_world: font_family font_identifier;
 coding_scheme font_coding_scheme;
 font_face_byte 254-2 round designsize; fi % Dover code for CM; 154==AM
tracingstats:=10; % temporary
end.